|
|
Post by bplus on Jun 15, 2023 10:32:23 GMT -5
Charlie's post on the old Point trick used to enlarge text reminded me of my little tut, creating a scrolling text "LED" screen in 3 Steps: _Title "Building a Scrolling LED Screen" ' b+ 2021-05-08
Screen _NewImage(1200, 160, 32)
_Delay .25 'give screen time to load
_ScreenMove _Middle 'and center screen
'scroll some text
Text$ = "Try scrolling me for awhile until you got it, then press a key... "
lenText = Len(Text$)
startTextPos = 1
'put text in sign 15 chars wide in middle of screen print the message moving down 1 character evey frame
_Title "Building a Scrolling LED Screen: Step 1 get some code to scroll your message in middle of screen."
Do
k$ = InKey$
Cls
' two pieces of text? when get to end of text will have less than 15 chars to fill sign so get remainder from front
len1 = lenText - startTextPos
If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
' locate at middle of screen for 15 char long sign
_PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
startTextPos = startTextPos + 1
If startTextPos > lenText Then startTextPos = 1
_Display ' no blinking when clear screen so often
_Limit 5 ' slow down to see scroll
Loop Until Len(k$)
' OK now for the enLARGE M E N T using _PutImage
' our little sign is 16 pixels high and 8 * 15 chars pixels wide = 120
Dim sign As Long
sign = _NewImage(120, 16, 32) ' we will store the print image here
' _PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]][_SMOOTH]
' use same pixel location to _printString as for _PutImage Source rectangle ie (sx1, sy1), -step( sign width and height)
' test screen capture with _putimage and then blowup with _putimage
'_PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
'Cls
'_PutImage , sign, 0 ' stretch to whole screen
'_Display
'now that that works do it on the move
' about here I resized the screen to 1200 x 160 to make the text scalable X's 10 ie 120 x 10 wide and 16 x 10 high
_Title "Building a Scrolling LED Screen: Step 2 Blow it up by using _PutImage twice once to capture, then to expand"
k$ = ""
Do
k$ = InKey$
Cls
' two pieces of text? when get to end of text will have less than 15 chars to fill sign so get remainder from front
len1 = lenText - startTextPos
If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
' locate at middle of screen for 15 char long sign
_PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
_PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
Cls
_PutImage , sign, 0 ' stretch to whole screen
_Display ' no blinking when clear screen so often
_Limit 5 ' slow down to see scroll
startTextPos = startTextPos + 1
If startTextPos > lenText Then startTextPos = 1
Loop Until Len(k$)
' now for a mask just draw a grid test grid draw here
'For x = 0 To _Width Step 10 ' verticals
' Line (x, 0)-(x + 3, _Height), &HFF000000, BF
'Next
'For y = 0 To _Height Step 10
' Line (0, y)-(_Width, y + 3), &HFF000000, BF
'Next
_Title "Building a Scrolling LED Screen: Step 3 Mask or Cover the thing with a grid or grate."
' here is the whole code with all setup variables
k$ = ""
Do
k$ = InKey$
Cls
' two pieces of text? when get to end of text will have less than 15 chars to fill sign so get remainder from front
len1 = lenText - startTextPos
If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
' locate at middle of screen for 15 char long sign
_PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
_PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
Cls
_PutImage , sign, 0 ' stretch to whole screen
' now for a mask just draw a grid best to draw this and copy and layover screen as another layer
' here QB64 is fast evough to redarw each time
For x = 0 To _Width Step 10 ' verticals
Line (x, 0)-(x + 3, _Height), &HFF000000, BF
Next
For y = 0 To _Height Step 10
Line (0, y)-(_Width, y + 3), &HFF000000, BF
Next
_Display ' no blinking when clear screen so often
_Limit 5 ' slow down to see scroll
startTextPos = startTextPos + 1
If startTextPos > lenText Then startTextPos = 1
Loop Until Len(k$)
Step 1 + Just scroll some text in the middle of the screen size you want to convert to:  Step 2 + Enlarging the text (a mod of the old trick Charlie's is doing in BAM):  Step 3 + adding a grid to mask the print for appearance of many LED lights:  |
|
|
|
Post by The Joyful Programmer on Jul 7, 2023 2:20:00 GMT -5
You got to love scrolling LEDs! Here's a couple I created 8-9 years ago in QB64:
Here's the source code to the RED LED SCROLLING SIGN:
' *************************************************************************************************
' * *
' * Walter's LED sign - By member Waltersmind. *
' * *
' * Created: May 04, 2014 *
' * *
' *************************************************************************************************
TYPE LEDCharacter
Image AS _UNSIGNED LONG
ImageWidth AS _UNSIGNED INTEGER
ImageHeight AS _UNSIGNED INTEGER
END TYPE
DIM SHARED ScreenWidth AS _UNSIGNED LONG
DIM SHARED ScreenHeight AS _UNSIGNED LONG
DIM SHARED MainScreen AS _UNSIGNED LONG
DIM SHARED BackBuffer AS _UNSIGNED LONG
DIM SHARED SaveBuffer AS _UNSIGNED LONG
DIM SHARED ScrollSpeed AS INTEGER
DIM SHARED Character(126) AS LEDCharacter
DIM SHARED LEDPixelSize AS _UNSIGNED INTEGER
DIM SHARED LEDBulbSize AS _UNSIGNED INTEGER
DIM SHARED LEDScreenWidth AS _UNSIGNED INTEGER
DIM SHARED LEDScreenHeight AS _UNSIGNED INTEGER
DIM SHARED LEDPanelWidth AS _UNSIGNED INTEGER
DIM SHARED LEDPanelHeight AS _UNSIGNED INTEGER
DIM SHARED LEDImageOn AS _UNSIGNED LONG
DIM SHARED LEDImageOff AS _UNSIGNED INTEGER
DIM SHARED CurrentLine AS _UNSIGNED INTEGER
DIM SHARED CurrentCharacter AS _UNSIGNED INTEGER
DIM SHARED CurrentPixelDelay AS _UNSIGNED INTEGER
DIM SHARED CurrentPixelCounter AS _UNSIGNED INTEGER
DIM SHARED CurrentCharacterPixel AS _UNSIGNED INTEGER
DIM SHARED PixelSpeed AS _FLOAT
DIM SHARED CurrentPixelState AS _UNSIGNED LONG
DIM SHARED Message(25) AS STRING
Message(0) = "This is a single-color LED sign test by Waltersmind (Walt Whitman). This is only a test."
Message(1) = "O Captain! My Captain! Our fearful trip is done."
Message(2) = "The ship has weather'd every rack, the prize we sought is won,"
Message(3) = "The port is near, the bells I hear, the people all exulting,"
Message(4) = "While follow eyes the steady keel, the vessel grim and daring;"
Message(5) = "But O heart! Heart! Heart!"
Message(6) = "O the bleeding drops of red,"
Message(7) = "Where on the deck my Captain lies,"
Message(8) = "Fallen cold and dead."
Message(9) = "O Captain! my Captain! Rise up and hear the bells;"
Message(10) = "Rise up-for you the flag is flung-for you the bugle trills,"
Message(11) = "For you bouquets and ribbon'd wreaths-for you the shores a-crowding,"
Message(12) = "For you they call, the swaying mass, their eager faces turning;"
Message(13) = "Here Captain! dear father! "
Message(14) = "The arm beneath your head!"
Message(15) = "It is some dream that on the deck,"
Message(16) = "You've fallen cold and dead."
Message(17) = "My Captain does not answer, his lips are pale and still,"
Message(18) = "My father does not feel my arm, he has no pulse nor will,"
Message(19) = "The ship is anchor'd safe and sound, its voyage closed and done,"
Message(20) = "From fearful trip the victor ship comes in with object won;"
Message(21) = "Exult O shores, and ring O bells!"
Message(22) = "But I with mournful tread,"
Message(23) = "Walk the deck my Captain lies,"
Message(24) = "Fallen cold and dead."
Message(25) = "O Captain! My Captain! By: Walt Whitman - From the book: Leaves of Grass... The End..."
LEDPixelSize = 6 '12 'The LED pixel unit that contains the LED bulb
LEDBulbSize = 4 '8 ' The size of the LED bulb
LEDPanelWidth = 200 ' The width is in LED pixels (a space that contains one LED bulb), not monitor pixels.
LEDPanelHeight = 16 ' This is the actual height the current font uses.
CurrentPixelDelay = LEDPanelWidth + 10 ' The delay in LED units before the next line is displayed.
PixelSpeed = 1 ' Change this to speed up the scrolling.
ScreenWidth = LEDPanelWidth * LEDPixelSize
ScreenHeight = LEDPanelHeight * LEDPixelSize
MainScreen = _NEWIMAGE(ScreenWidth, ScreenHeight, 32)
BackBuffer = _NEWIMAGE(ScreenWidth, ScreenHeight, 32)
SaveBuffer = _NEWIMAGE(ScreenWidth, ScreenHeight, 32)
LEDImageOn = _NEWIMAGE(LEDPixelSize, LEDPixelSize, 32)
LEDImageOff = _NEWIMAGE(LEDPixelSize, LEDPixelSize, 32)
SCREEN MainScreen
' *** Get read to draw the turned-off LED bulb
_DEST LEDImageOff
' *** Draw LED background
LINE (0, 0)-(LEDPixelSize, LEDPixelSize), _RGB(32, 0, 0), BF
' *** Draw grey-filled gradient circle that represents the turned-off LED bulb
FOR CircleSize% = LEDBulbSize TO 1 STEP -1
Red% = 64 - CircleSize% * 6
Green% = 0 ' Red%
Blue% = 0 'Red%
Colr& = _RGB(Red%, Green%, Blue%)
CIRCLE (LEDPixelSize / 2 - 1, LEDPixelSize / 2 - 1), CircleSize% / 2 + 0.05, Colr&
PAINT (LEDPixelSize / 2 - 1, LEDPixelSize / 2 - 1), Colr&, Colr&
NEXT
' *** Get ready to draw the turned-on LED bulb
_DEST LEDImageOn
' *** Draw LED Background
LINE (0, 0)-(LEDPixelSize, LEDPixelSize), _RGB(64, 0, 0), BF
' *** Draw filled gradient circles that represents the turned-on LED bulb
FOR CircleSize% = LEDBulbSize TO 1 STEP -1
Red% = (LEDBulbSize - CircleSize%) * 35 + 140
Green% = 0 'Red%
Blue% = 0
Colr& = _RGB(Red%, Green%, Blue%)
CIRCLE (LEDPixelSize / 2 - 1, LEDPixelSize / 2 - 1), CircleSize% / 2 + 0.05, Colr&
PAINT (LEDPixelSize / 2 - 1, LEDPixelSize / 2 - 1), Colr&, Colr&
NEXT
' Due to some strange thing with printing a text character to an exact text character size image,
' we can not print text straight to the characters image. So here we draw it to the backbuffer.
_DEST BackBuffer
' *** Create images for each character
FOR C = 32 TO 126
CharLength% = _PRINTWIDTH(CHR$(C))
Character(C).Image = _NEWIMAGE(CharLength%, 16, 32)
Character(C).ImageWidth = CharLength%
Character(C).ImageHeight = 16
' If you change this color value, you must change it below in the testing part. Please note, the
' color value cannot be &HFFFFFFFF. When we use POINT below, if there is an error reading the pixel
' color, it returns &HFFFFFFFF or -1. This is a single-color LED sample, so the color used is not
' at all important.
COLOR &HFFFF0000
LOCATE 1, 1
PRINT CHR$(C)
' Now we copy the text image over to the character image.
_PUTIMAGE (0, 0), BackBuffer, Character(C).Image
NEXT
' *** Draw blank LED panel to the backbuffer.
FOR PanelHeight~% = 0 TO LEDPanelHeight - 1
FOR PanelWidth~% = 0 TO LEDPanelWidth - 1
_PUTIMAGE (PanelWidth~% * LEDPixelSize, PanelHeight~% * LEDPixelSize), LEDImageOff, BackBuffer
NEXT
NEXT
' Copy the back buffer over to the main screen image.
_PUTIMAGE (0, 0), BackBuffer, MainScreen
CurrentLine = 0 ' We will start off with the zero-index of the message$ array.
CurrentCharacter = 1 ' Set to the first character of the line. It cannot be zero.
CurrentPixelCounter = 30 ' This is the first LED-pixel delay value. It is lower than the default value.
CurrentCharacterPixel = 0 ' Always start with zero here.
' *** Now the setup part is done, let's now animate our happy little LED sign.
DO
_LIMIT 25
' Get the current character in the line
MIDCharacter% = ASC(MID$(Message(CurrentLine), CurrentCharacter, 1))
' Change the source to the current characters image
_SOURCE Character(MIDCharacter%).Image
' Check to see if we are still in the display delay.
IF CurrentPixelCounter > 0 THEN
' If we are here than scroll everything left by pixel amount until we are no longer in the delay.
CurrentPixelCounter = CurrentPixelCounter - PixelSpeed
' Since the source and destination image cannot be the same, we have to copy part of the LED image
' we know will still be on screen when scrolled, to the save buffer.
_PUTIMAGE (0, 0), BackBuffer, SaveBuffer, (LEDPixelSize * PixelSpeed, 0)-(ScreenWidth, ScreenHeight)
' Copy the save buffer image back into the back buffer at the far left of the image. This simulates scrolling.
_PUTIMAGE (0, 0), SaveBuffer, BackBuffer
ELSE
' Since the source and destination image cannot be the same, we have to copy part of the LED image
' we know will still be on screen when scrolled, to the save buffer.
_PUTIMAGE (0, 0), BackBuffer, SaveBuffer, (LEDPixelSize * PixelSpeed, 0)-(ScreenWidth, ScreenHeight)
' Copy the save buffer image back into the back buffer at the far left of the image. This simulates scrolling.
_PUTIMAGE (0, 0), SaveBuffer, BackBuffer
' Now we draw the number of vertical slices of the character defined by "PixelSpeed".
' X% is basically 0 to PixelSpeed-1.
FOR PixelX% = (LEDPanelWidth - PixelSpeed) TO (LEDPanelWidth - 1)
FOR PixelY% = 0 TO LEDPanelHeight - 1
' Get the current character pixel X position.
CharX% = CurrentCharacterPixel + (PixelX% - (LEDPanelWidth - PixelSpeed))
' Get the color of the current pixel in the characters image.
CurrentPixelState = POINT(CharX%, PixelY%)
' Check to see if it contains the previously defined color value.
IF CurrentPixelState = &HFFFF0000 THEN
' If it does, draw the LED ON image.
_PUTIMAGE (PixelX% * LEDPixelSize, PixelY% * LEDPixelSize), LEDImageOn, BackBuffer
ELSE
' If it doesn't, then draw the LED OFF image.
_PUTIMAGE (PixelX% * LEDPixelSize, PixelY% * LEDPixelSize), LEDImageOff, BackBuffer
END IF
NEXT
NEXT
' Get the next character pixel X-offset.
CurrentCharacterPixel = CurrentCharacterPixel + PixelSpeed
' See if it is outside the current characters width.
IF CurrentCharacterPixel >= (Character(MIDCharacter%).ImageWidth) THEN
' If it is, reset the X-position back to 0.
CurrentCharacterPixel = 0
' Go to the next character in the current line.
CurrentCharacter = CurrentCharacter + 1
' See if exuasted the characters in this line.
IF CurrentCharacter > LEN(Message(CurrentLine)) THEN
' We have, so go to the next line.
CurrentLine = CurrentLine + 1
' Reset the character position to the first position.
CurrentCharacter = 1
' Here we setup the delay to show the next line
CurrentPixelCounter = CurrentPixelDelay
' Check to see if we ran out of lines.
IF CurrentLine > UBOUND(message) THEN
' We have so reset the current line to the first one in our array.
CurrentLine = 0
END IF
END IF
END IF
END IF
' Copy the complete back buffer on to the main screen.
_PUTIMAGE (0, 0), BackBuffer, MainScreen
' Show it.
_DISPLAY
LOOP UNTIL _KEYHIT 'WHILE INKEY$ = ""
SYSTEM
Here's the source code to the FULL COLOR SCROLLING LED SIGN:
DIM CurrentScreen AS LONG
DIM LedSign AS LONG
DIM LedSignBG AS LONG
DIM LedSignDup AS LONG
DIM LedSignTitle AS LONG
DIM BulbMask AS LONG
DIM ScreenWidth AS _UNSIGNED INTEGER
DIM ScreenHeight AS _UNSIGNED INTEGER
DIM ImgMode AS _UNSIGNED _BYTE
DIM LedWidth AS _UNSIGNED _BYTE
DIM LedHeight AS _UNSIGNED _BYTE
DIM LedBulbSize AS _UNSIGNED _BYTE
DIM ScrollLeft AS _BYTE
ScreenWidth = 800
ScreenHeight = 600
ImgMode = 32
LedWidth = 87
LedHeight = 57
LedBulbSize = 8
ScrollLeft = 1
CurrentScreen = _NEWIMAGE(ScreenWidth, ScreenHeight, ImgMode)
LedSign = _NEWIMAGE(LedWidth, LedHeight, ImgMode)
LedSignDup = _NEWIMAGE(LedWidth, LedHeight, ImgMode)
LedSignBG = _NEWIMAGE(LedWidth, LedHeight, ImgMode)
LedSignTitle = _NEWIMAGE(LedWidth, LedHeight, ImgMode)
BulbMask = _NEWIMAGE(LedBulbSize + 1, LedBulbSize + 1, ImgMode)
SCREEN CurrentScreen
' *** SETUP THE BULB MASK TO GIVE THE APPEARANCE OF A ROUND BULB
_DEST BulbMask
FOR rad = LedBulbSize * 2 TO LedBulbSize / 2 STEP -.2
CIRCLE (LedBulbSize / 2 - .5, LedBulbSize / 2 - .5), rad, _RGBA(20, 0, 0, 128)
NEXT
FOR rad = LedBulbSize TO 2 STEP -.2
CIRCLE (LedBulbSize / 2 - .5, LedBulbSize / 2 - .5), rad, _RGBA(0, 0, 0, (40 / LedBulbSize) * rad)
NEXT
' *** SETUP THE TITLE IMAGE
_DEST LedSignTitle
COLOR _RGB(255, 231, 174), _RGBA(0, 0, 0, 0)
FOR y = 0 TO 2
FOR x = 0 TO 2
_PRINTSTRING (x + 30, y + 5), "THE"
_PRINTSTRING (x + 20, y + 20), "JOYFUL"
_PRINTSTRING (x + 3, y + 35), "PROGRAMMER"
NEXT
NEXT
COLOR _RGB(36, 92, 123), _RGBA(0, 0, 0, 0)
_PRINTSTRING (31, 6), "THE"
_PRINTSTRING (21, 21), "JOYFUL"
_PRINTSTRING (4, 36), "PROGRAMMER"
DO
_LIMIT 60
_DEST LedSignBG
_PUTIMAGE (0, 0), LedSignBG, LedSignDup
_PUTIMAGE (0, 0), LedSignDup, LedSignBG, (ScrollLeft, 0)-(_WIDTH(LedSign), _HEIGHT(LedSign))
LINE (LedWidth - ScrollLeft, 0)-(LedWidth, LedHeight), _RGB(45, 0, 0), BF
FOR i = 1 TO 3
LINE (RND * LedWidth, RND * LedHeight)-(RND * LedWidth, RND * LedHeight), _RGB(RND * 128, RND * 128, RND * 128), BF
NEXT
_PUTIMAGE (110, 10), LedSignBG, CurrentScreen
_PUTIMAGE (210, 10), LedSignTitle, CurrentScreen
_PUTIMAGE (0, 0), LedSignBG, LedSign
_PUTIMAGE (0, 0), LedSignTitle, LedSign
_DEST LedSign
LINE (0, 0)-(LedWidth - 1, LedHeight - 1), _RGBA(RND * 128 + 127, RND * 128 + 127, RND * 128 + 127, 255), B
_PUTIMAGE (10, 10), LedSign, CurrentScreen
DrawLED 10, 75, LedBulbSize, LedSign, CurrentScreen, BulbMask
_DISPLAY
LOOP WHILE INKEY$ = ""
SYSTEM
SUB DrawLED (x AS INTEGER, y AS INTEGER, BulbSize AS _UNSIGNED _BYTE, ImgSrc AS LONG, ImgDest AS LONG, BulbMask AS LONG)
DIM BulbSpacing AS _UNSIGNED _BYTE
DIM DestX1 AS INTEGER
DIM DestY1 AS INTEGER
DIM DestX2 AS INTEGER
DIM DestY2 AS INTEGER
BulbSpacing = 1 + BulbSize
FOR by = 0 TO _HEIGHT(ImgSrc) - 1
FOR bx = 0 TO _WIDTH(ImgSrc) - 1
DestX1 = x + bx * BulbSpacing
DestY1 = y + by * BulbSpacing
DestX2 = x + bx * BulbSpacing + BulbSize - 1
DestY2 = y + by * BulbSpacing + BulbSize
_PUTIMAGE (DestX1, DestY1)-(DestX2, DestY2), ImgSrc, ImgDest, (bx, by)-(bx, by)
_PUTIMAGE (DestX1, DestY1), BulbMask, ImgDest
NEXT
NEXT
END SUB
ENJOY!!!
|
|
