Random Tessellation

Inspired by Charlies work in BAM you see here at this forum and I want to share with people new to QB64 so I have started from scratch with a QB64 version:
_Title "Tessellation use b to toggle to 1 color and black or full color"
' b+ 2023-05-09 - Tiling with a pattern
'
' Inspired by Charlie's BAM example:
' https://qb64phoenix.com/forum/showthread.php?tid=1646&pid=15772#pid15772
'
' But I also wanted to try a colorized version.
'
'  So use b key to toggle between:
'  1. a mod of Charlies version with different pixel block size with black backgrounds
'  2. the colorized version which reminds me of Magic Eye Art
'
DefLng A-Z
Screen _NewImage(800, 600, 12) ' only 16 colors here
_ScreenMove 250, 50
Dim Shared Pix '   Pix is number of pixels to Tile side
Dim Shared Scale ' Change a pixel to a bigger square block for not so subtle patterns
Dim Shared Tile '  Handle that stores Tile Image in memory to call up with _PutImage
Dim Shared B '     Set color mode from Full 16 colors Rainbow to 1 like for printing a label
Do
   If InKey$ = "b" Then B = 1 - B '    toggle coloring mode on a b keypress
   MakeTile '                          create a new random tiling pattern
   Tessellate '                        tile the screen with it
   _PrintString (740, 580), "ZZZ..." ' Show user we are sleeping awaiting a key press
   Sleep
Loop Until _KeyDown(27) ' quit when detect escape key on sleep

Sub MakeTile ' make a random tile to Tesselate according to B Mode coloring
   Pix = Int(Rnd * 9) + 4 '           sets tile size: pix X pix or a 4X4 to 12X12 Tile coloring
   Scale = Int(Rnd * 6) + 4 '         to change pixels to square blocks
   If Tile Then _FreeImage Tile '     throw old image away
   Tile = _NewImage(Scale * Pix - 1, Scale * Pix - 1) '   make new one
   _Dest Tile '                       draw in the memory area Tile not on screen
   oneColor = Int(Rnd * 15) + 1 '     one color and black background for B Mode
   For y = 0 To Scale * Pix - 1 Step Scale
       For x = 0 To Scale * Pix - 1 Step Scale
           If B Then
               If Rnd < .5 Then c = 0 Else c = oneColor 'one color and black background for B Mode
           Else
               c = Int(Rnd * 16)
           End If
           Line (x, y)-Step(Scale, Scale), c, BF  ' draw square that is scaled pixel
       Next
   Next
   _Dest 0
End Sub

Sub Tessellate ' just covering the screen with our Tile
   For y = 0 To _Height Step Scale * Pix
       For x = 0 To _Width Step Scale * Pix
           _PutImage (x, y)-Step(Scale * Pix - 1, Scale * Pix - 1), Tile, 0
       Next
   Next
End Sub

Colorized:



Black and some one other color:


"ZZZ..." in Screen shots means we are Sleeping, get it ZZZ... asleep, waiting for keypress to wake and tile screen with another random generated Tile with random pixel blocks (min 4) and random colors (16) and random scale min X4.

If you press b key you toggle Coloring Modes and esc key quits.